チートシート¶

YAYA の書き方を 1 ページにまとめた早見表です。くわしい説明は、各項目のリンク先を見てください。

YAYA の考え方¶

• 辞書は関数の集まりです。名前 { ... } の形で定義し、OnBoot のようにイベント名にすると、そのイベントの応答になります。
• 関数の中の式や文字列が 1 行ずつ「出力の候補」になります。関数が呼ばれると、候補の中から 1 つがランダムに選ばれて返ります。代入（_a = 1）のような文は候補になりません。
• 文字列は "..." で囲みます。さくらスクリプトも文字列なので、必ず囲みます。
• 変数は型を持ちます（整数・実数・文字列・配列・ハッシュ）。宣言は要りません。_ で始まる名前はローカル変数です。
• 関数の外には、文も変数も書けません。#define などのプリプロセッサだけは外に書けます。
• if while の条件式は、カッコで囲んでも囲まなくても構いません（if (_a == 1) も if _a == 1 も同じ）。for foreach もヘッダ全体を ( ) で囲めます（Tc603-6 以降。それ以前はエラー）。
• 記号は半角で書きます（全角の （ や ＋ は使えません）。

関数の書き方¶

OnBoot
{
  _name = "さくら"
  "\0\s[0]こんにちは、%(_name)さん。\e"
  "\0\s[0]起動しましたね。\e"
}

• 上の例では、"\0\s[0]こんにちは…" と "\0\s[0]起動しましたね。\e" のどちらかがランダムに返ります（_name = … は候補になりません）。
• 候補は 1 行に 1 つです。"a" "b" のように 1 行に並べるとエラーになります。"a" / "b" の / は割り算で、候補の区切りではありません。
• 単独の行に -- を書くと、前後の候補を別々のグループとして、それぞれから 1 つずつ選んでつなぎます（関数）。
• { は関数名と同じ行にも、次の行にも書けます。
• コメントは // 行末まで と /* 複数行 */ です。
• 1 行に複数の文を書くときは ; で区切ります（_a = 1 ; _b = 2）。

引数と返り値¶

候補の選び方¶

関数名の後ろに : で付けます（Seq : sequential）。

選択方式とは別に、次の修飾子も付けられます。

OnTest : _pool
{
  "x"
  {
    "y"
    "z"
  }
}

• _pool がないと、内側の { } は全体で 1 つの候補です（x が 1/2、y z が 1/4 ずつ）。_pool を付けると x y z が 1/3 ずつになります。
• if の条件が偽なら、その中身の候補は加わりません。if 条件 { "b" "c" } で「条件が真のときだけ候補が増える」書き方ができます。
• while for foreach の中の候補は、繰り返すたびに 1 つずつ加わります。
• nonoverlap : { のように選択方式を書いたブロックは、ばらされず 1 つの候補のままです。

詳細は関数。

値と型¶

• 文字列の中の " は、重ねて書きます（"1""2" → 1"2）。
• 型は GETTYPE で調べます（VOID は 0、整数は 1、実数は 2、文字列は 3、汎用配列は 4、ハッシュは 5）。
• 実数を文字列にすると小数点以下 6 桁になります（3.0/4*100 → 75.000000）。
• 整数同士の割り算は切り捨てです（4/3 → 1）。片方を実数にすると実数になります。

変数¶

• 未定義の変数は、計算では 0、文字列では空文字列になります（UNDEF + 1 は 1）。
• 数字で始まる名前や、予約語・関数名と同じ名前は使えません（予約語）。

演算子¶

優先度の高い順です（算術演算）。

• 0 が偽、0 以外が真です。比較の結果は 1 か 0 です。
• "or" _in_ "World" は、右の文字列に左が含まれるとき 1 になります。
• + は、どちらかが文字列なら連結です（"5" + 1 は "51"）。* は数値として計算します（"5" * 2 は 10）。
• == は大文字と小文字を区別します（"abc" == "ABC" は 0）。
• 三項演算子（? :）はありません。

制御構造¶

if _a < 3
{
  "小"
}
elseif _a < 10
{
  "中"
}
else
{
  "大"
}

case _name
{
  when "さくら" { "さくらだね" }
  when "うにゅう", "うに" { "うにゅうだね" }
  others { "だれ？" }
}

• case の when にはリテラルだけが書けます（変数や式は不可）。範囲は 3-5 や "a"-"d" と書きます。
• when と others は、case 式 に続く { } の中に書きます。{ を付けずに when を続けると、読み込み時にエラー（E0051）になります。
• ループの繰り返し回数には上限があります（既定は 10000 回。looplimit）。超えると OnLoopLimit が呼ばれます。
• while 1 は無限ループです。必ず break を書いてください。

文字列への埋め込み¶

詳細は文字列埋め込み。

配列¶

_a = (10, 20, 30)
_a[1]            // 20
_a[0,1]          // 範囲（10,20）
_a ,= 40         // 末尾に追加
_a = ("先頭", _a) // 先頭に追加
_a + "!"         // 全要素に演算（10!,20!,…）
ARRAYSIZE(_a)    // 要素数

• 範囲外の要素は VOID です（GETTYPE(_a[9]) は 0）。
• 簡易配列は文字列のまま添字で読み書きします（_s = "a,b,c" → _s[1] は b）。区切りは _s[1,"|"] のように指定します。
• 配列の要素は ARRAYSIZE、検索は ASEARCH、並べ替えは ASORT、分割は SPLIT を使います。

ハッシュ（Tc600-3以降）¶

_h = IHASH("name", "さくら", "age", 16)
_h["name"]        // さくら
_h["age"] += 1    // 複合代入も使える
_h["none"]        // VOID（キーが無い）
foreach _h ; _k, _v { … }

• ハッシュは、先に IHASH() で作っておく必要があります。
• 要素はキーの順に並びます（入れた順ではありません）。
• 要素には配列やハッシュも入れられます（値の入れ子）。

プリプロセッサ¶

詳細はプリプロセッサ。

設定ファイル（yaya.txt）¶

dic, basis.dic
charset, UTF-8
log, executelog.txt

• 設定ファイルは DLL 名に .txt を付けた名前です（yaya.txt）。// と /* */ でコメントが書けます。
• 設定ファイルが無い、または読み込む辞書が 1 つも無いと、シェルモードになります。送った式をそのまま EVAL して返すので、式の動作確認に使えます（基礎設定）。

詳細は基礎設定。

よく使う関数¶

全部の一覧はシステム関数一覧にあります。

関連¶

• ゴーストの作り方
• 里々からの移行
• AYAからの移行